***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Feb 01, 2018                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt SS10150HE-AU A K 
.param
+vc0 = 2.061e-3
+vc1 = 1.434e-4
+rr1 = 1.018e-3
+vc2 = 3.458e-2
+tc1 = 5.913e-3
+tc2 = 8.526e-3
+tc3 = 6.284e-2
+tc4 = 4.286e-2
gdiode K A value={(vc0+vc1*v(K,A)*(1.0+tc1*(temp-25)*exp(tc2*(temp-25)))+rr1*exp(vc2*v(K,A)))*1e-6*(1.0+tc3*(temp-25)*exp(tc4*(temp-25)))}
d1 A K sbd
.model sbd d
***** flag parameter ***
+level = 1                     
***** dc model parameter ***
+ibv = 0.5e-3       
+ is = 4.278e-9
+  n = 1.106 
+ rs = 1.256e-1
+ikf = 1e-2
+ bv = 165                       
***** capacitance parameter ***
+cjo = 8.376e-11
+  m = 4.814e-1
+ vj = 5.930e-1 
+ fc = 0.5                      
***** temperature coefficient ***
+tnom = 25                     
+  eg = 7.641e-1            
+ xti = 3             
+trs1 = -4.878e-3
+trs2 = -1.727e-5  
+tikf = -1e-3
.ends SS10150HE-AU
*$
